"Zeger Knaepen" <zeg### [at] povplacecom> wrote:
> could you give the entire source ?
>
> cu!

this piece of code shows the problem -

//_______________________________

global_settings {
        assumed_gamma 2.2
        max_trace_level 150
        noise_generator 2
}

#declare hfscalx = 80;
#declare hfscalz = 60;

camera {
        orthographic
        location <0,100,0>
        look_at  <0,0,0>
        right hfscalx*x
        up hfscalz*z
}

background {color rgb 0.5}
//plane {y, -1 texture {pigment {color rgb 0.5} finish {ambient 1 diffuse
0}}}

#declare thingy =
disc {
        0,y,1
        texture {
                pigment {
                        cylindrical
                        color_map {
                                [0.0  rgb 0.5 transmit 0 filter 0]
                                [0.3  rgb 1.0 transmit 0 filter 0]
                                [0.9  rgb 0.0 transmit 0 filter 0]
                                [1.0  rgb 0.0 transmit 0 filter 0]
                        }
                }
                finish {ambient 1 diffuse 0}
        }
        scale 4
        hollow double_illuminate
}

#declare areal = plane {y,0}
#declare r1 = seed(1);
#declare n = 0;
#while (n < 200)
        #declare X = rand(r1)*hfscalx*2;
        #declare Z = rand(r1)*hfscalz*2;
        #declare Norm = <0,0,0>;
        #declare Start = <X-hfscalx,100,Z-hfscalz>;
        #declare Inter = trace (areal,Start,-y,Norm);
        #if (vlength (Norm) != 0)
                object {
                        thingy
                        scale (0.7+0.6*rand(r1))
                        translate <Inter.x,0,Inter.z>
                }
                #declare n = n+1;
        #end
#end
//______________________________________________

Post a reply to this message